理解 GROUPBY

GROUPBY 函数在语法上类似于 SUMMARIZE，但不提供 SUMMARIZE 生成的筛选上下文，也不提供可转换的行上下文。它的目的是通过 CURRENTGROUP 函数对分组后的每一行应用迭代器。

GROUPBY

GROUPBY ( <Table>, [<GroupBy_ColumnName>, ...], [<Name>, <Expression>], [ … ] )

创建一个包含指定列的分组表。

示例用法

例如，你可以这样使用 GROUPBY 重写 SUMMARIZE 的第一个案例：

EVALUATE
GROUPBY (
    Sales,
    'Date'[Calendar Year Number],
    "Quantity", SUMX ( CURRENTGROUP (), Sales[Quantity] )
)

你必须在表最外层的列表达式中使用 CURRENTGROUP，因此它不支持多层迭代函数嵌套。如果需要生成动态 DAX 查询，并且希望对另一个表表达式的结果应用特定的聚合，GROUPBY 函数会非常有用。

SUMMARIZE 的局限

除了性能方面的限制，SUMMARIZE 的另一个限制是不能聚合在其内部创建的派生列，例如，观察下面的查询，它看起来应该为每个产品类别返回相关子类别平均价格的最大值。

EVALUATE
ADDCOLUMNS (
    SUMMARIZE (
        ADDCOLUMNS (
            SUMMARIZE (
                Product, 
                'Product Category'[Category], 
                'Product Subcategory'[Subcategory] 
            ),
            "Average Price", CALCULATE ( AVERAGE ( Product[Unit Price] ) )
        ),
        'Product Category'[Category]
    ),
    "Max SubCat Avg Price", CALCULATE ( MAX ( [Average Price] ) )
)

但实际上查询会得到一个错误的 MAX ( [Average Price] )。原因是 DAX 只允许你聚合物理列，在聚合函数的本质一文中，我们介绍过类似的等价表达式：

MAX ( table[expression] ) = MAXX ( table, table[expression] )

如果你尝试聚合在查询中新建的列（例如本例中[Average Price]），引擎将无法找到相应的 MAXX 函数。为了获得正确的结果，你需要移除外层的 SUMMARIZE，直接对新建的列进行操作

EVALUATE
ADDCOLUMNS (
    VALUES ( 'Product Category'[Category] ),
    "Max SubCat Avg Price", CALCULATE (
        MAXX (
            ADDCOLUMNS (
                SUMMARIZE (
                    Product,
                    'Product Category'[Category],
                    'Product Subcategory'[Subcategory]
                ),
                "Average Price", CALCULATE ( AVERAGE ( Product[Unit Price] ) )
            ),
            [Average Price]
        )
    )
)

改写后的查询得到了正确结果

但是这种写法的问题也很明显，代码冗长且计算效率不高。如果希望同时计算最低和最高平均价格，你需要复制两份 SUMMARIZE，这会导致更长的执行时间。

使用 GROUPBY 代替 SUMMARIZE

GROUPBY 可以用于聚合查询内部的派生列，避免 ADDCOLUMNS+SUMMARIZE 的冗长代码。但是，即使是 GROUPBY，我们也不能直接使用聚合函数，

GROUPBY 移除空值

GROUPBY 会自动从结果中删除 CURRENTGROUP 列中有空白结果的行。大多数情况这种行为都是符合直觉的：从结果中删除那些“空白行”，但是当你将使用 CURRENTGROUP 的计算与其他计算混合使用时，结果可能有些出乎意料。

例如，考虑以下查询，它只考虑平均价格高于 500 的产品，并在另一列中返回产品类别名称的字符串长度。

EVALUATE
GROUPBY (
    GROUPBY (
        Product,
        'Product Category'[Category],
        'Product Subcategory'[Subcategory],
        "Average Price", AVERAGEX ( CURRENTGROUP (), Product[Unit Price] )
    ),
    'Product Category'[Category],
    "Max SubCat Avg Price", MAXX (
        CURRENTGROUP (),
        IF ( [Average Price] > 500, [Average Price], BLANK () )
    ),
    "Len", MAXX ( CURRENTGROUP (), LEN ( 'Product Category'[Category] ) )
)

尽管可以对所有产品类别统计名称的长度，但结果也只包括至少一个子类别平均价格高于 500 的产品类别。

查询结果

值得注意的是，由于 GROUPBY 并非迭代函数，所以它既不生成行上下文，也不生成筛选上下文，所以计算字符串长度的代码不能直接引用当前行，仍然要套用 CURRENTGROUP ()函数。

如果需要显示价格列为空的值，只需将 MAXX 函数中的 BLANK()替换为 0

EVALUATE
GROUPBY (
    GROUPBY (
        Product,
        'Product Category'[Category],
        'Product Subcategory'[Subcategory],
        "Average Price", AVERAGEX ( CURRENTGROUP (), Product[Unit Price] )
    ),
    'Product Category'[Category],
    "Max SubCat Avg Price",
        MAXX (
            CURRENTGROUP (),
            IF ( [Average Price] > 500, [Average Price], 0)
        ),
    "Len", MAXX ( CURRENTGROUP (), LEN ( 'Product Category'[Category] ) )
)

完整结果