从数据到信息
从信息到洞察

BLANK

返回空白。

语法

BLANK ( )

返回值

标量 一个任意类型的值,空值没有数据类型

备注

  • BLANK 值在与其他值比较时自动转换类型。
  • 检查一个值是否为 BLANK 的正确方法是使用运算符 == 或 ISBLANK 函数。不要使用运算符 = 。
  • 运算符==是一个 “严格等于 “的运算符,它将 BLANK 与 0 或空字符串区别对待。

BLANK 不对应 SQL 中的 NULL。DAX 中的 BLANK 不遵循 NULL 在 SQL 中的计算逻辑。在中间结果可能是 BLANK 的表达式中,必须注意这种区别。

在 Excel 2016 之后的版本、以及 Power BI Desktop 中,布尔表达式只能返回 TRUE 或者 FALSE,在这种情况下,BLANK 将被强制转换为 FALSE。

示例

常用运算中的 BLANK

表达式 结果
BLANK ( ) 空值
BLANK ( ) = 0 True
BLANK ( ) == 0 False
BLANK ( ) == BLANK ( ) True
BLANK ( ) && TRUE False
BLANK ( ) | | TRUE True
BLANK ( ) + 0 0
BLANK ( ) – 4 -4
4 / BLANK ( ) Infinite
BLANK ( ) * 4 空值
BLANK ( ) / 4 空值
INT ( BLANK ( ) ) 空值

BLANK 用于比较

当 BLANK 与 0 或空字符串进行比较时,BLANK 会被转换。为了避免这种情况,在需要准确判断的场合,需要使用 ISBLANK 或者 严格相等运算符 ==。

表达式 结果
IF ( BLANK (), “true”, “false” ) false
IF ( ISBLANK ( BLANK () ), “true”, “false” ) true
IF ( BLANK () = True, “true”, “false” ) false
IF ( BLANK () = False, “true”, “false” ) true
IF ( BLANK () = 0, “true”, “false” ) true
IF ( BLANK () = “”, “true”, “false” ) true

自动将空白值转换为零或空字符串的行为可能会产生意料之外的副作用。例如,思考以下两种表达式在[measure]分别为 0,”” 和 BLANK 时会返回什么结果

IF (
    [measure] = BLANK(),
    "is blank",
    IF (
        VALUE ( [measure] ) = 0,
        "is zero", "other"
    )
)
IF (
    VALUE ( [measure] ) = 0,
    "is blank",
    IF (
        [measure] = BLANK(),
        "is zero", "other"
    )
)
表达式 1 在三种情况下都返回 is blank,也就是 IF 只执行第一分支,并未执行后面的判断。原因是 BLANK 发生了强制转换。

表达式 2 在[measure]为空字符串的情况下报错,因为 VALUE 不能将其转换为有效数值,其他两种情况都返回 is blank

SWITCH 和 IF 的区别

当你使用 SWITCH 的时候,公式行为将有所不同,因为 SWITCH 在内部使用 ISBLANK 函数比较空白值。在下表中可以看到,使用空值(或返回空值的表达式)比较的结果与在列表中找到的第一个空值或 False 匹配。

SWITCH (
    BLANK(),
    0, "zero",
    True, "true",
    BLANK(), "blank",
    False, "false"
)
SWITCH (
    BLANK(),
    0, "zero",
    True, "true",
    False, "false",
    BLANK(), "blank"
)

值得注意的是,与 False 的比较可能得到意外结果。为了避免任何问题,应该把与 BLANK 的比较放在 SWITCH 条件列表中的第一个。

SWITCH 和 IF 的这种区别还体现在对表表达式的结果做判断的情况下,观察以下表达式

SWITCH (
    COUNTROWS ( FILTER ( Query1, False ) ),
    0, "zero",
    1, "one",
    "other"
)

IF (
    COUNTROWS ( FILTER ( Query1, False ) ) = 0,
    "zero",
    "other"
)

结合上面的介绍,你应该可以判断出第一个 SWITCH 表达式返回 other,而第二个 IF 表达式返回 zero。如果想让第一个表达式得到正确的结果,可以这样改写:

SWITCH (
    COUNTROWS ( FILTER ( Query1, False ) ) + 0,
    0, "zero",
    1, "one",
    "other"
)

处理布尔表达式中的 BLANK

当表达式涉及布尔数据类型的列时,会有一种特殊的行为。老版本的 DAX 允许从布尔表达式中返回 BLANK,而较新的版本(Power BI/Excel 2016/SSAS Tabular 2016)只从 IF 等逻辑表达式中返回 TRUE 或 FALSE。如果复制表达式中的布尔列,表中现有的 BLANK 将被保留。否则,逻辑表达式中的 BLANK 将被转换为 FALSE。

你可以在下面的例子中看到,当结果是布尔数据类型的情况下,IF 永远不会返回 BLANK 值。

IF ( 1 = 1, BLANK(), TRUE ) = FALSE
IF ( 1 <> 1, BLANK(), TRUE ) = TRUE
IF ( 1 = 1, TRUE, BLANK() ) = TRUE
IF ( 1 <> 1, TRUE, BLANK() ) = FALSE

扩展阅读

 

说点什么

1000
 
鼓掌微笑开心憧憬爱你色并不觉得吃瓜doge二哈喵喵思考笑哭捂脸悲伤大哭抓狂汗偷笑打脸捂眼黑线问号晕拜拜闭嘴衰咒骂ok作揖
  订阅本文评论  
提醒
DAX 圣经

DAX 函数大全

DAX 查询

DAX 运算符